TEMPLATE = lib
CONFIG += staticlib c++11
DEFINES += CHESSBOARDDETECTOR_LIBRARY

# 包含路径
INCLUDEPATH += ./Inc
INCLUDEPATH += ./_Inc
INCLUDEPATH += ../../Utils/VrCommon/Inc

# 头文件
HEADERS += \
    Inc/IChessboardDetector.h \
    _Inc/ChessboardDetector.h

# 源文件
SOURCES += \
    Src/ChessboardDetector.cpp

# OpenCV 配置
win32 {
    # Windows 平台使用 OpenCV 3.2.0
    INCLUDEPATH += $$PWD/../../SDK/OpenCV320/include

    CONFIG(release, debug|release): {
        LIBS += -L$$PWD/../../SDK/OpenCV320/x64/vc14/lib
        LIBS += -lopencv_world320
    }
    else:CONFIG(debug, debug|release): {
        LIBS += -L$$PWD/../../SDK/OpenCV320/x64/vc14/lib
        LIBS += -lopencv_world320d
    }

    QMAKE_CXXFLAGS += /utf-8
    TARGET = ChessboardDetector
}

unix {
    # Unix/Linux 平台使用 OpenCV 3.2.0 ARM
    INCLUDEPATH += $$PWD/../../SDK/OpenCV320/Arm/aarch64/include
    LIBS += -L$$PWD/../../SDK/OpenCV320/Arm/aarch64
    LIBS += -lopencv_core -lopencv_imgproc -lopencv_calib3d -lopencv_features2d

    QMAKE_CXXFLAGS += -fPIC
    target.path = /usr/lib
}

!isEmpty(target.path): INSTALLS += target