# CalibView - 手眼标定测试工具
QT += core gui widgets

CONFIG += c++17
CONFIG -= app_bundle

# Windows平台UTF-8编码支持
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CXXFLAGS += /bigobj
}

TARGET = CalibView
TEMPLATE = app

# 项目目录
INCLUDEPATH += $$PWD/Inc
INCLUDEPATH += $$PWD/../../Module/HandEyeCalib/Inc
INCLUDEPATH += $$PWD/../../Module/HandEyeCalib/_Inc
INCLUDEPATH += $$PWD/../../Utils/VrCommon/Inc
INCLUDEPATH += $$PWD/../../SDK/eigen-3.3.9

# VrEyeView 集成
INCLUDEPATH += $$PWD/../VrEyeView/Inc
INCLUDEPATH += $$PWD/../../Module/ChessboardDetector/Inc
INCLUDEPATH += $$PWD/../../Device/VrEyeDevice/Inc

# VzNLSDK 头文件路径
INCLUDEPATH += $$PWD/../../SDK/Device/VzNLSDK/Inc

# RobotView 集成
INCLUDEPATH += $$PWD/../RobotView
INCLUDEPATH += $$PWD/../../Robot/FairinoWrapper
INCLUDEPATH += $$PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/src/include/Robot-CN
INCLUDEPATH += $$PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/src/include

# 定义静态库模式（不导入）
DEFINES += FAIRINO_WRAPPER_LIB

# OpenCV 配置
win32 {
    INCLUDEPATH += $$PWD/../../SDK/OpenCV320/include
}

unix {
    INCLUDEPATH += $$PWD/../../SDK/OpenCV320/Arm/aarch64/include
}

# 头文件
HEADERS += \
    Inc/CalibViewMainWindow.h \
    Inc/CalibDataWidget.h \
    Inc/CalibResultWidget.h \
    ../RobotView/MainWindow.h \
    ../VrEyeView/Inc/VrEyeViewWidget.h

# 源文件
SOURCES += \
    main.cpp \
    Src/CalibViewMainWindow.cpp \
    Src/CalibDataWidget.cpp \
    Src/CalibResultWidget.cpp \
    ../RobotView/MainWindow.cpp \
    ../VrEyeView/Src/VrEyeViewWidget.cpp

# 资源文件
RESOURCES += resource/resource.qrc

# Windows 应用图标
RC_ICONS = resource/logo.ico

# Windows平台库链接
win32:CONFIG(release, debug|release): {
    LIBS += -L../../Module/HandEyeCalib/release                 -lHandEyeCalib
    LIBS += -L../../Utils/VrCommon/release                      -lVrCommon
    LIBS += -L../../Utils/VrUtils/release                       -lVrUtils
    LIBS += -L../../Utils/CloudUtils/release                    -lCloudUtils
    LIBS += -L$$OUT_PWD/../../Robot/FairinoWrapper/release/     -lFairinoWrapper
    LIBS += -L$$OUT_PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/release/ -lfairino
    LIBS += -L$$OUT_PWD/../../Module/ChessboardDetector/release -lChessboardDetector
    LIBS += -L$$OUT_PWD/../../Device/VrEyeDevice/release        -lVrEyeDevice
    LIBS += -L$$PWD/../../SDK/OpenCV320/Windows/vc14/Release    -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L../../Module/HandEyeCalib/debug                   -lHandEyeCalib
    LIBS += -L../../Utils/VrCommon/debug                        -lVrCommon
    LIBS += -L../../Utils/VrUtils/debug                         -lVrUtils
    LIBS += -L../../Utils/CloudUtils/debug                      -lCloudUtils
    LIBS += -L$$OUT_PWD/../../Robot/FairinoWrapper/debug/       -lFairinoWrapper
    LIBS += -L$$OUT_PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/debug/ -lfairino
    LIBS += -L$$OUT_PWD/../../Module/ChessboardDetector/debug   -lChessboardDetectord
    LIBS += -L$$OUT_PWD/../../Device/VrEyeDevice/debug          -lVrEyeDeviced
    LIBS += -L$$PWD/../../SDK/OpenCV320/Windows/vc14/Release    -lopencv_world320
}

# Unix平台库链接
unix {
    LIBS += -L../../Module/HandEyeCalib -lHandEyeCalib
    LIBS += -L../../Utils/VrCommon -lVrCommon
    LIBS += -L$$OUT_PWD/../../Robot/FairinoWrapper/ -lFairinoWrapper
    LIBS += -L$$OUT_PWD/../../SDK/Robot/fairino-cpp-sdk/libfairino/ -lfairino
    LIBS += -L$$OUT_PWD/../../Module/ChessboardDetector -lChessboardDetector
    LIBS += -L$$OUT_PWD/../../Device/VrEyeDevice -lVrEyeDevice
    LIBS += -L$$PWD/../../SDK/OpenCV320/Arm/aarch64
    LIBS += -lopencv_core -lopencv_imgproc -lopencv_calib3d -lopencv_features2d -lopencv_imgcodecs -lopencv_highgui
    QMAKE_CXXFLAGS += -fPIC
}

win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../SDK/Device/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../SDK/Device/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../SDK/Device/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}

# Windows系统库
win32 {
    LIBS += -lAdvapi32
    LIBS += -lws2_32
}

DEFINES += _USE_MATH_DEFINES

# Default rules for deployment
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target