# VrEyeView - 相机图像查看与标定板检测工具
QT += core gui widgets

CONFIG += c++17
CONFIG -= app_bundle

# Windows平台UTF-8编码支持
win32-msvc {
    QMAKE_CXXFLAGS += /utf-8
    QMAKE_CXXFLAGS += /bigobj
}

TARGET = VrEyeView
TEMPLATE = app

# 项目目录
INCLUDEPATH += $$PWD/Inc
INCLUDEPATH += $$PWD/../../Device/VrEyeDevice/Inc
INCLUDEPATH += $$PWD/../../Device/VrEyeDevice/_Inc
INCLUDEPATH += $$PWD/../../Module/ChessboardDetector/Inc
INCLUDEPATH += $$PWD/../../Module/ChessboardDetector/_Inc
INCLUDEPATH += $$PWD/../../Utils/VrCommon/Inc

# VzNLSDK 头文件路径
INCLUDEPATH += $$PWD/../../SDK/Device/VzNLSDK/Inc

# 头文件
HEADERS += \
    Inc/VrEyeViewWidget.h

# 源文件
SOURCES += \
    main.cpp \
    Src/VrEyeViewWidget.cpp


win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../SDK/Device/VzNLSDK/Windows/x64/Release
    LIBS += -lVzKernel -lVzNLDetect -lVzNLGraphics
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../SDK/Device/VzNLSDK/Windows/x64/Debug
    LIBS += -lVzKerneld -lVzNLDetectd -lVzNLGraphicsd
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../SDK/Device/VzNLSDK/Arm/aarch64
    LIBS +=  -lVzEyeSecurityLoader-shared -lVzKernel -lVzNLDetect -lVzNLGraphics
}


# OpenCV 配置
win32:CONFIG(release, debug|release): {
    LIBS += -L$$PWD/../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L$$PWD/../../SDK/OpenCV320/Windows/vc14/Release -lopencv_world320
}
else:unix:!macx: {
    LIBS += -L$$PWD/../../SDK/OpenCV320/Arm/aarch64 -lopencv_core -lopencv_imgproc -lopencv_highgui
}

# Windows平台库链接
win32:CONFIG(release, debug|release): {
    LIBS += -L../../Utils/CloudUtils/release          -lCloudUtils
    LIBS += -L../../Device/VrEyeDevice/release        -lVrEyeDevice
    LIBS += -L../../Module/ChessboardDetector/release -lChessboardDetector
    LIBS += -L../../Utils/VrCommon/release            -lVrCommon
    LIBS += -L../../Utils/VrUtils/release             -lVrUtils
}
else:win32:CONFIG(debug, debug|release): {
    LIBS += -L../../Utils/CloudUtils/debug            -lCloudUtils
    LIBS += -L../../Device/VrEyeDevice/debug          -lVrEyeDeviced
    LIBS += -L../../Module/ChessboardDetector/debug   -lChessboardDetectord
    LIBS += -L../../Utils/VrCommon/debug              -lVrCommon
    LIBS += -L../../Utils/VrUtils/debug               -lVrUtils
}

# Unix平台库链接
unix {
    LIBS += -L../../Device/VrEyeDevice                -lVrEyeDevice
    LIBS += -L../../Module/ChessboardDetector         -lChessboardDetector
    LIBS += -L../../Utils/VrCommon                    -lVrCommon
    LIBS += -L$$PWD/../../SDK/VzNLSDK/Linux/Arm/aarch64/lib     -lVzKernel
    QMAKE_CXXFLAGS += -fPIC
}

# Windows系统库
win32 {
    LIBS += -lAdvapi32
    LIBS += -lws2_32
}

DEFINES += _USE_MATH_DEFINES

# Default rules for deployment
qnx: target.path = /tmp/$${TARGET}/bin
else: unix:!android: target.path = /opt/$${TARGET}/bin
!isEmpty(target.path): INSTALLS += target